Power Query Язык М №1. Простые выражения, let

При желании можно вообще не использовать выражение let.

Можно просто открыть расширенный редактор и ввести в нем какое-нибудь число или текст.

Оба примера содержат M-код, который возвращает значение, числовое или текстовое, и не содержит выражение let.

let — это выражение, которое возвращает значение. Выражение let позволяет нам создавать промежуточные выражения, результаты которых сохраняются в переменные.

Когда мы делим большое выражение на промежуточные нам удобнее читать код.

На переменные мы можем ссылаться в дальнейшем.

let
   // первая переменная
   m = 79.2,
   // вторая переменная
   h_squared = Number.Power(1.775, 2)
in
   // ссылаемся на обе переменные
   Number.Round(m / h_squared, 2)

Несмотря на то, что let нужен, чтобы создавать переменные, на одну или несколько из которых предполагается ссылка в выражении in, можно и не ссылаться на предыдущие шаги в in.

Power Query не будет считать это бессмысленное выражение ошибкой.

let
    // первая переменная
    m = 79.2,
    // вторая переменная
    h_squared = Number.Power(1.775, 2)
in
    // результат без ссылок ни на одну переменную
    2 * 2

Чаще всего в in присутствует только одна переменная — самая последняя.

Оба кода справа возвращают один и тот же результат.

В первом случае между let и in два промежуточных шага, в in присутствуют ссылки на обе переменные.

Во втором случае между let и in существуют три переменная, в in есть ссылка только на одну последнюю переменную.

Ссылка на две переменные в in:

let
    // первая переменная
    m = 79.2,

    // вторая переменная
    h_squared = Number.Power(1.775, 2)
in
    // ссылаемся на обе переменные
    Number.Round(m / h_squared, 2)

Одна переменная в in:

let
   m         = 79.2,
   h_squared = Number.Power(1.775, 2),
   bmi       = Number.Round(m / h_squared, 2)
in
   // одна переменная в in
   bmi

Так как let — это выражение, которое возвращает значение, то его можно использовать везде, где мы хотим вычислить какие-то значения.

let
   // первый вложенный блок let
   p1 = 
      let
         m = 79
      in
         10 * m,
   // второй вложенный блок let
   p2 = 
      let
         h = 177.5
      in
         6.25 * h,
   // третий вложенный блок let
   p3 = 
      let
         yo = 32
      in
         5 + yo
in
   Number.Round(5 + p1 + p2 - p3, 0)