Power Query Язык М №3. Создание функций М 2

Функцию можно сохранить в какую переменную. Эта переменная будет являться названием функции.

В дальнейшем можно вызвать эту функцию по этому названию, передав нужные параметры.

let
    // Создаем функцию
    fn_mult =
        (x as number, y as number) =>
        x * y,
    // Вызываем функцию
    result = fn_mult(5, 6)
in
    result

Существуют функции, которые в качестве параметра принимают функцию.

Например, третий параметр функции Table.AddColumn — это функция генерации столбца или ColumnGenerator.

В данном примере мы создадим функцию fn_mult, а потом применим ее в качестве параметра ColumnGenerator функции Table.AddColumn.

let
  // Создадим таблицу пример
  source =
      #table({"Monthly Payment", "Term"},
             {
               {1423, 48},
               {2771, 48},
               {3947, 48},
               {4952, 48},
               {5836, 48},
               {6395, 48},
               {7932, 48},
               {8900, 48},
               {9250, 48},
               {10211, 48}
             }),
  fn_mult =
    (row)=>
      row[Monthly Payment] * row[Term],
  
  // Передаем функцию как параметр
  col_total = Table.AddColumn(source,
                              "Total Payments",
                              fn_mult,
                              Number.Type)
in
  col_total

Если мы собираемся использовать функцию в параметре другой функции, то нам не обязательно для этого иметь отдельную переменную.

В этом примере мы сделаем все то же, что и в предыдущем, но функцию определим прямо в самом параметре без создания отдельной переменной для нее.

let
  // Создадим таблицу пример
  source =
      #table({"Monthly Payment", "Term"},
             {
               {1423, 48},
               {2771, 48},
               {3947, 48},
               {4952, 48},
               {5836, 48},
               {6395, 48},
               {7932, 48},
               {8900, 48},
               {9250, 48},
               {10211, 48}
             }),
  
  // Передаем функцию как параметр
  col_total = Table.AddColumn(source,
                              "Total Payments",
                              (row)=>
                                row[Monthly Payment] * row[Term],
                              Number.Type)
in
  col_total

Ключевое слово each является сокращением для конструкции (_)=>.

В предыдущих примерах мы применяли конструкцию (row)=>. Вместо row можно было придумать абсолютно любое имя. Общепринятым является использование символа подчеркивания _.

Вместо конструкции (_)=> мы можем просто ввести слово each.

Также нам мы можем сократить и ссылки на столбцы. Вместо row[Monthly Payment] и row[Term] мы просто можем ввести [Monthly Payment] и [Term].

let
  // Создадим таблицу пример
  source =
      #table({"Monthly Payment", "Term"},
             {
               {1423, 48},
               {2771, 48},
               {3947, 48},
               {4952, 48},
               {5836, 48},
               {6395, 48},
               {7932, 48},
               {8900, 48},
               {9250, 48},
               {10211, 48}
             }),
  
  // Передаем функцию как параметр
  col_total = Table.AddColumn(source,
                              "Total Payments",
                              each _[Monthly Payment] * _[Term],
                              Number.Type)
in
  col_total