Power Query. Формулы М. Функция Table.TransformColumns

---

Описание

В этом уроке мы научимся работать с объединенными ячейками по вертикали, а также научимся правильно делить ячейки, в которых находится несколько единиц данных.

Напротив одной ячейки находится несколько ячеек с данными. Нам нужно все это преобразовать в нормальную таблицу.

Решение

С помощью функции Table.TransformColumns мы преобразуем каждый столбец таблицы с операцией Split.

После преобразования каждого столбца мы заново создадим таблицу из этих преобразованных столбцов.

Далее нам останется лишь немного почистить данные.

Примененные функции

• Excel.CurrentWorkbook
• Table.TransformColumns
• Text.Split
• Character.FromNumber
• Text.From
• Table.AddColumn
• Table.FromColumns
• Table.SelectColumns
• Table.ExpandTableColumn
• Table.FillDown
• Table.TransformColumnTypes
• Int64.Type

Код

let
   source = Excel.CurrentWorkbook(){[Name = "Таблица1"]}[Content],
   cols_transform = Table.TransformColumns(
      source,
      {
         {
            "Артикул",
            each try
               Text.Split(_, Character.FromNumber(10))
            otherwise
               {Text.From(_)},
            type text
         },
         {
            "Количество",
            each try
               Text.Split(_, Character.FromNumber(10))
            otherwise
               {Text.From(_)},
            type text
         },
         {
            "Цена",
            each try
               Text.Split(_, Character.FromNumber(10))
            otherwise
               {Text.From(_)},
            type text
         },
         {
            "Счет",
            each try
               Text.Split(_, Character.FromNumber(10))
            otherwise
               {Text.From(_)},
            type text
         }
      }
   ),
   table_add_col = Table.AddColumn(
      cols_transform,
      "Таблица",
      each Table.FromColumns({[Счет], [Артикул], [Количество], [Цена]})
   ),
   cols_select = Table.SelectColumns(table_add_col, {"Таблица"}),
   col_expand = Table.ExpandTableColumn(
      cols_select,
      "Таблица",
      {"Column1", "Column2", "Column3", "Column4"},
      {"Счет", "Артикул", "Количество", "Цена"}
   ),
   col_fill_down = Table.FillDown(col_expand, {"Счет"}),
   types = Table.TransformColumnTypes(
      col_fill_down,
      {
         {"Счет", Int64.Type},
         {"Артикул", type text},
         {"Количество", Int64.Type},
         {"Цена", type number}
      }
   )
in
   types