Power Query Продвинутый №8. Объект Table (Таблица)

Для подключения к таблице на листе Excel текущей книги используется функция Excel.CurrentWorkbook.

Для подключения к таблице в другой книге Excel применятся функция Excel.Workbook.

let
   source = Excel.CurrentWorkbook(){[Name = "Таблица1"]}[Content], 
   cos_types = Table.TransformColumnTypes(
      source, 
      {{"Дата", type datetime}, {"Код", type text}, {"Сумма", Int64.Type}}
   )
in
   cos_types

Создадим следующую таблицу:

let
   source = #table(
      {"Имя", "Фамилия", "Должность"}, 
      {
         {"Владимир", "Путьн", "Президент"}, 
         {"Дмитрий", "Медведев", "Председатель правительства"}
      }
   )
in
   source

Ссылаясь на столбец таблицы мы получаем объект List со всеми значениями этого столбца.

let
    source = table_created[Должность]
in
    source

Ссылаясь на строку таблицы мы получим объект Record.

let
    source = sample_table{1}
in
    source

Ссылаясь на ячейку в результате мы получим значение этой ячейки.

let
    source = sample_table[Дата]{1}
in
    source

В результате получим числовое значение количества строк в таблице.

let
    source = Table.RowCount(sample_table)
in
    source

В результате получим числовое значение количества столбцов в таблице.

let
    source = Table.ColumnCount(sample_table)
in
    source

Проверяем является ли таблица пустой. Получим значение TRUE/FALSE.

let
    source = Table.IsEmpty(sample_table)
in
    source

Получим значение из первой строки первого столбца. Такой же результат мы можем получить и просто сославшись на самую первую ячейку.

let
    source = Table.FirstValue(sample_table)
in
    source

Получим таблицу такого вида с описательными статистиками и другой дополнительной информацией.

let
    source = Table.Profile(sample_table)
in
    source

В результате получится объект List из заголовков таблицы.

let
    source = Table.ColumnNames(sample_table)
in
    source

Преобразовать таблицу в список столбцов. Элементов в списке будет столько, сколько столбцов в таблице. Каждый элемент списка — это список со значениями столбцов таблицы.

Обратной функцией является функция Table.FromColumns. Она наоборот создаст таблицу из списка столбцов.

// Таблицу превратить в список, где каждый элемент - это столбец
let
    source = Table.ToColumns(sample_table)
in
    source

// Из списка, где каждый элемент - это столбец создать таблицу
let
    source = TableToColumns,
    tab_from_cols = Table.FromColumns(source)
in
    tab_from_cols

Получится список. Каждый элемент списка — это строка исходной таблицы, в которой значений разделены заданным разделителем.

Обратной функцией является функция Table.FromList. Она превратит список в таблицу.

// Преобразовать таблицу в список
let
   source = sample_table, 
   cols_types = Table.TransformColumnTypes(
      source, 
      {{"Дата", type text}, {"Код", type text}, {"Сумма", type text}}
   ), 
   tab_to_list = Table.ToList(
      cols_types, 
      Combiner.CombineTextByDelimiter(" -- ")
   )
in
   tab_to_list

// Преобразовать список в таблицу
let
    source = TableToList,
    tab_from_list = Table.FromList(source, Splitter.SplitTextByDelimiter(" -- "))
in
    tab_from_list

Функция Table.ToRecords преобразовывает таблицу в список. Каждый элемент списка — это запись, которая является строкой таблицы.

Обратная функция Table.FromRecords наоборот создаст таблицу из списка записей.

// Преобразовать таблицу в список записей
let
    source = Table.ToRecords(sample_table)
in
    source

// Преобразовать список записей в таблицу
let
   source = TableToRecords, 
   tab_from_list = Table.FromList(
      source, 
      Splitter.SplitByNothing(), 
      null, 
      null, 
      ExtraValues.Error
   ), 
   tab_from_recs = Table.FromRecords(tab_from_list[Column1])
in
   tab_from_recs

Функция Table.ToRows преобразовывает таблицу в список. Каждый элемент списка является списком значений строки.

Обратная функция Table.FromRows создаст таблицу из списка строк.

let
    source = Table.ToRows(sample_table)
in
    source

let
    source = TableToRows,
    tab_from_rows = Table.FromRows(source)
in
    tab_from_rows