Power Query Продвинутый №9. Ссылки 1

В этом уроке мы будем использовать простую таблицу-пример, на элементы которой и будем ссылаться.

Назовем эту таблицу sample_table.

Для создания таблицы будем использовать функцию #table.

let
   source = #table(
      {"Бренд", "Цена", "Количество"},
      {
         {"Apple", 56990, 5},
         {"Samsung", 44990, 3},
         {"Xiaomi", 25890, 10}
      }
   )
in
   source

Сначала научимся ссылаться на элемент списка.

Для ссылки на элемент списка нужно ввести название списка и в фигурных скобках указать индекс нужного элемента.

Индексация в Power Query начинается с нуля.

Сошлемся на второй элемент списка.

let
   source = {"А" .. "К"},
   ref    = source{1}
in
   ref

Запись — это строка таблицы.

Чтобы сослаться на строку таблицы нужно ввести название этой таблицы и в фигурных скобках ввести индекс строки.

Индексация в Power Query начинается с нуля.

Сошлемся на вторую строку таблицы.

let
   source = sample_table,
   ref    = source{1}
in
   ref

Чтобы получить только отдельные поля записи нужно сначала сослаться на запись, а потом в квадратных скобках перечислить нужные поля.

Название каждого поля тоже вводится в квадратных скобках.

let
   source = sample_table,
   ref    = source{1}[[Бренд], [Количество]]
in
   ref

Мы можем ссылаясь на запись указать какое именно значение поля нас интересует.

Для этого в фигурных скобках вместо индекса нужно ввести условие. Само условие вводится в квадратных скобках.

let
   source = sample_table,
   ref    = source{[Бренд = "Xiaomi"]}
in
   ref

Если мы захотим сослаться на запись с указанием нужного значения поля, а такого значения в столбце не окажется, то Power Query вернет ошибку.

Чтобы ошибки не получилось нужно добавить к ссылке вопросительный знак.

В таком случае мы получим значение null, если значение не будет найдено.

let
   source = sample_table,
   ref    = source{[Бренд = "Huawei"]}?
in
   ref