Power Query. Практика. Нарастающий итог 3 (усложненный)

---

Описание

В этом уроке мы еще раз режим задачу с нарастающим итогом, но пример будет немного сложнее. Его отличием от предыдущих уроков про нарастающий итог будет в том, что нарастающий итог будет вычисляться для каждой отдельной группы.

Решения

Для решения задачи мы создадим пользовательскую функцию из трех шагов.

В первом шаге функции мы отберем товар, по которому выполняется нарастающий итог. Во втором выберем первые N строк. В третьем найдем сумму по столбцу.

Ключом к решению задачи будет столбец индекса. Именно из него будет браться значение N строк для пользовательской функции.

В этой задачи мы изучим/повторим функционал:

• Группировка
• Пользовательская функция
• Table.AddIndexColumn

Примененные функции

• Table.SelectRows
• Table.FirstN
• List.Sum
• Table.TransformColumnTypes
• Table.Group
• Table.AddColumn
• Table.AddIndexColumn
• Table.SelectColumns
• Table.ExpandTableColumn

Код

Код пользовательской функции:

(Таблица, Наименование, КоличествоСтрок) =>
   let
      Товар = Table.SelectRows(
         Таблица,
         each ([Наименование товара] = Наименование)
      ),
      Индекс = Table.FirstN(Товар, КоличествоСтрок),
      Сумма = List.Sum(Индекс[Количество])
   in
      Сумма

Код решения:

let
   source = Excel.CurrentWorkbook(){[Name = "Таблица2"]}[Content],
   types = Table.TransformColumnTypes(
      source,
      {
         {"Период", type date},
         {"Наименование товара", type text},
         {"Количество", type number}
      }
   ),
   table_group = Table.Group(
      types,
      {"Наименование товара"},
      {{"Таблица", each _, type table}}
   ),
   table_add_col = Table.AddColumn(
      table_group,
      "Таблица Индекс",
      each Table.AddIndexColumn([Таблица], "Индекс", 1)
   ),
   cols_select = Table.SelectColumns(table_add_col, {"Таблица Индекс"}),
   col_expand = Table.ExpandTableColumn(
      cols_select,
      "Таблица Индекс",
      {"Период", "Наименование товара", "Количество", "Индекс"},
      {"Период", "Наименование товара", "Количество", "Индекс"}
   ),
   table_add_col_fn = Table.AddColumn(
      col_expand,
      "Нарастающий итог",
      each Ф_НарастающийИтог(col_expand, [Наименование товара], [Индекс])
   )
in
   table_add_col_fn