Power Query. Формулы М. Нарастающий итог 2

Описание

В этом уроке мы изучим 3 способа создания нарастающих итогов в Power Query.

1 из этих способов мы уже изучили и только повторим. 2 способа будут для нас новыми. Также мы изучим несколько новых функций.

Решение

Пользовательская функция

Нужно создать пользовательскую функцию, которая в первом шаге отбирает N строк, а во втором суммирует столбец. Выходит, что у функции всего 2 параметра: таблица и количество строк.

Чтобы передать этой функции параметр «количество строк» мы создадим столбец индекса

Использование List.Range

Для решения с List.Range нужно сначала создать столбец индекса. В функцию List.Range мы передадим в качестве значения окончания диапазона число из столбца индекса. Полученный диапазон мы суммируем.

Примененные функции

• Table.TransformColumnTypes
• Int64.Type
• Table.AddIndexColumn
• Table.AddColumn
• Number.Type
• Table.FirstN
• List.Sum
• List.Range
• List.Accumulate

Код

Использование функции

Код функции:

(Таблица, КоличествоСтрок) =>
   let
      select_rows = Table.FirstN(Таблица, КоличествоСтрок),
      sum         = List.Sum(select_rows[Сумма продаж])
   in
      sum

Код таблицы:

let
   source = Excel.CurrentWorkbook(),
   get_table = source{[Name = "sales"]}[Content],
   types = Table.TransformColumnTypes(
      get_table,
      {{"Дата", type date}, {"Сумма продаж", Int64.Type}}
   ),
   table_add_Index = Table.AddIndexColumn(types, "Индекс", 1, 1),
   table_add_col = Table.AddColumn(
      table_add_Index,
      "Нарастающий итог",
      each Ф_НарастающийИтог(table_add_Index, [Индекс]),
      Number.Type
   )
in
   table_add_col

Использование List.Range

let
   source = Excel.CurrentWorkbook(),
   get_table = source{[Name = "sales"]}[Content],
   types = Table.TransformColumnTypes(
      get_table,
      {{"Дата", type date}, {"Сумма продаж", Int64.Type}}
   ),
   table_add_index = Table.AddIndexColumn(types, "Индекс", 1, 1),
   table_add_col = Table.AddColumn(
      table_add_index,
      "Список продаж",
      each table_add_index[Сумма продаж]
   ),
   table_add_col_2 = Table.AddColumn(
      table_add_col,
      "Диапазон",
      each List.Range([Список продаж], 0, [Индекс])
   ),
   table_add_col_3 = Table.AddColumn(
      table_add_col_2,
      "Нарастающий итог",
      each List.Sum([Диапазон]),
      Number.Type
   )
in
   table_add_col_3

Использование List.Accumulate

let
   source = Excel.CurrentWorkbook(){[Name = "sales"]}[Content],
   types = Table.TransformColumnTypes(
      source,
      {{"Дата", type date}, {"Сумма продаж", Int64.Type}}
   ),
   table_add_index = Table.AddIndexColumn(types, "Индекс", 1, 1),
   table_add_col = Table.AddColumn(
      table_add_index,
      "Список продаж",
      each List.Range(table_add_index[Сумма продаж], 0, [Индекс])
   ),
   table_add_col_2 = Table.AddColumn(
      table_add_col,
      "Нарастающий итог",
      each List.Accumulate(
         [Список продаж],
         0,
         (state, current) => state + current
      ),
      Number.Type
   )
in
   table_add_col_2