Power Query. Основы. Ссылка на другую строку

Описание

В этом уроке вы научитесь как сослаться на другую строку в Power Query. Мы разберем эту технику на примере нахождения процентного отличия.

Допустим у нас таблица с продажами по дням. Нам нужно добавить столбец, в котором мы хотим увидеть процентный прирост текущего дня по отношению к предыдущему, который находится в предыдущей строке.

Решение

Чтобы решить эту задачу на понадобится использовать следующие приемы:

• Ссылки в Power Query
• Столбец индекса

Столбец индекса нам будет нужен, чтобы найти предыдущую строку. Предыдущая строка имеет тот же индекс, но на 1 меньше.

Примененные функции

• Table.TransformColumnTypes
• Table.AddIndexColumn
• Table.AddColumn
• Percentage.Type
• Table.ReplaceErrorValues

Код

let
   source = Excel.CurrentWorkbook(){[Name = "Продажи"]}[Content], 
   types = Table.TransformColumnTypes(
      source, 
      {{"Дата", type date}, {"Продажи", type number}}
   ), 
   tab_add_idx = Table.AddIndexColumn(types, "Индекс", 0, 1), 
   tab_add_col = Table.AddColumn(
      tab_add_idx, 
      "Пользовательская", 
      each tab_add_idx[Продажи]{[Индекс]}
         - tab_add_idx[Продажи]{[Индекс] - 1}, 
      type number
   ), 
   tab_add_col_2 = Table.AddColumn(
      tab_add_col, 
      "Прирост", 
      each (
         tab_add_col[Продажи]{[Индекс]}
            - tab_add_col[Продажи]{[Индекс] - 1}
      )
         / tab_add_col[Продажи]{[Индекс] - 1}, 
      Percentage.Type
   ), 
   col_replace_errs = Table.ReplaceErrorValues(
      tab_add_col_2, 
      {{"Пользовательская", 0}, {"Прирост", 0}}
   )
in
   col_replace_errs