Power Query. Веб-запросы. JSON, Котировки Yahoo Finance 2

Описание

Вы хотите получить котировки с сайта Yahoo Finance. Как обработать формат JSON?

Мы разберем еще 1 способ получения котировок с сайта Yahoo Finance при помощи Excel. Этот способ будет намного быстрее предыдущего.

Решение

Для решения воспользуемся:

• Text.From
• Number.From
• Date.From
• DateTimeZone.LocalNow
• Table.FromColumns
• Table.ReplaceValue

Сначала мы вычислим сегодняшнюю дату в формате UNIX TIME с помощью формулы:

Text.From((Number.From(Date.From(DateTimeZone.LocalNow()))-Number.From(Date.From("01.01.1970"))) * 86400)

После этого мы запросим данные с помощью API:

Json.Document(
      Web.Contents(
         "https://query1.finance.yahoo.com/v8/finance/chart/MCD?interval=1d&period1=1&period2="
            & today
            & ""
      )
   )

Дальше останется только привести данные к надлежащему виду.

Примененные функции

• Json.Document
• Web.Contents
• Record.ToTable
• Table.Transpose
• Table.ExpandListColumn
• Table.Skip
• Table.ExpandRecordColumn
• Table.AddColumn
• Table.FromColumns
• Table.ReplaceValue
• Date.From
• Int64.From
• Replacer.ReplaceValue
• Text.From
• DateTimeZone.LocalNow
• Number.From

Код

let
   query = Json.Document(
      Web.Contents(
         "https://query1.finance.yahoo.com/v8/finance/chart/MCD?interval=1d&period1=1&period2="
            & today
            & ""
      )
   ), 
   chart = query[chart], 
   result = chart[result], 
   result1 = result{0}, 
   tab_from_record = Record.ToTable(result1), 
   get_value = tab_from_record{2}[Value], 
   get_tab_1 = Record.ToTable(get_value), 
   tab_transpose = Table.Transpose(
      Table.ExpandListColumn(get_tab_1, "Value")
   ), 
   rows_skip = Table.Skip(tab_transpose, 1), 
   col_expand_1 = Table.ExpandRecordColumn(
      rows_skip, 
      "Column1", 
      {"open", "close", "volume", "low", "high"}, 
      {"open", "close", "volume", "low", "high"}
   ), 
   col_expand_2 = Table.ExpandRecordColumn(
      col_expand_1, 
      "Column2", 
      {"adjclose"}, 
      {"adjclose"}
   ), 
   tab_add_col_1 = Table.AddColumn(
      col_expand_2, 
      "Пользовательская", 
      each Table.FromColumns(
         {
            tab_from_record{[Name = "timestamp"]}[Value], 
            [open], 
            [high], 
            [low], 
            [close], 
            [adjclose], 
            [volume]
         }, 
         {"Date", "O", "H", "L", "C", "Adj C", "Vol"}
      )
   ), 
   get_tab_2 = tab_add_col_1{0}[Пользовательская], 
   col_replace_value = Table.ReplaceValue(
      get_tab_2, 
      each [Date], 
      each Date.From("1.1.1970")
         + #duration(Int64.From([Date] / 60 / 60 / 24) - 1, 0, 0, 0), 
      Replacer.ReplaceValue, 
      {"Date"}
   )
in
   col_replace_value