Power Query. Практика. Обработка типичной выписки

---

Описание

Каждый день вам приходит выписка по эквайрингу. Она не очень удобна для дальнейшего анализа. Сперва преобразуем данные, чтобы можно было с ними работать.

Исходные данные выглядят так:

Решение

Сначала мы удалим лишние строки сверху. После этого мы создадим столбцы Адрес и POSID, данные из которых берутся из столбца N опер. Дальше останется только заполнить данные в двух новых столбцах вниз и отфильтровать строки.

Помимо пользовательского интерфейса Power Query мы воспользуемся:

• List.Select
• Text.Contains
• Text.BetweenDelimiters
• Text.AfterDelimiter
• Table.SelectRows

Примененные функции

• Table.Skip
• Table.PromoteHeaders
• Table.RemoveColumns
• List.Select
• Table.ColumnNames
• Text.Contains
• Comparer.OrdinalIgnoreCase
• Table.AddColumn
• Text.StartsWith
• Text.BetweenDelimiters
• Text.Trim
• Text.AfterDelimiter
• Table.FillDown
• Table.SelectRows

Код

let
   path = Excel.CurrentWorkbook(){[Name = "Путь"]}[Content]{0}[Column1]
      & "И_Выписка_2019.01.05.xlsx", 
   source = Excel.Workbook(File.Contents(path), null, true), 
   get_table = source[Data]{0}, 
   rows_skip = Table.Skip(get_table, 5), 
   tab_headers = Table.PromoteHeaders(
      rows_skip, 
      [PromoteAllScalars = true]
   ), 
   cols_select = Table.RemoveColumns(
      tab_headers, 
      List.Select(
         Table.ColumnNames(tab_headers), 
         each Text.Contains(_, "column", Comparer.OrdinalIgnoreCase)
      )
   ), 
   tab_add_col_1 = Table.AddColumn(
      cols_select, 
      "№ терминала", 
      each try
         
            if Text.StartsWith(
               [#"№ опер."], 
               "pos", 
               Comparer.OrdinalIgnoreCase
            )
            then
               Text.BetweenDelimiters([#"№ опер."], " ", " ")
            else
               null
      otherwise
         null
   ), 
   tab_add_col_2 = Table.AddColumn(
      tab_add_col_1, 
      "Адрес", 
      each Text.Trim(
         try
            
               if Text.StartsWith(
                  [#"№ опер."], 
                  "pos", 
                  Comparer.OrdinalIgnoreCase
               )
               then
                  Text.AfterDelimiter([#"№ опер."], ",")
               else
                  null
         otherwise
            null
      )
   ), 
   cols_fill_down = Table.FillDown(tab_add_col_2, {"№ терминала", "Адрес"}), 
   rows_select = Table.SelectRows(
      cols_fill_down, 
      each ([#"Дата опер."] <> null)
   )
in
   rows_select