Power Query. Ошибки. Подключиться к последнему файлу

---

Описание

Регулярно вам необходимо подключаться к последнему созданному файлу в папке с определенным названием. Например, файлы готовит другой отдела, а вы используете отчет другого отдела для подготовки своих отчетов.

Если вы жестко привяжетесь к какому-то файлу, то при добавлении нового автоматического переподключения не произойдет. Значит нужно будет постоянно менять ссылку. Это неудобно.

Решение

Задача решается очень просто. Самое главное — подключиться к папке, а не к файлу.

Для решения нам понадобятся следующие функции и возможности Power Query:

• Подключение к папке (Folder.Files)
• Фильтр по дате (Является последней)
• Ссылка на ячейку

Примененные функции

• Folder.Files
• Table.SelectRows
• List.Max
• Csv.Document
• QuoteStyle.None
• Table.Skip
• Table.PromoteHeaders
• Table.AddColumn
• Date.From
• Text.BetweenDelimiters
• Table.TransformColumnTypes
• Int64.Type

Код

let
   path = Excel.CurrentWorkbook(){[Name = "Путь"]}[Content]{0}[Column1], 
   source = Folder.Files(path), 
   rows_select_1 = Table.SelectRows(
      source, 
      each ([Name] = "КонецПериода.txt")
   ), 
   rows_select_2 = Table.SelectRows(
      rows_select_1, 
      let
         latest = List.Max(rows_select_1[Date created])
      in
         each [Date created] = latest
   ), 
   get_txt = rows_select_2[Content]{0}, 
   get_table = Csv.Document(
      get_txt, 
      [
         Delimiter  = "#(tab)", 
         Columns    = 10, 
         Encoding   = 65001, 
         QuoteStyle = QuoteStyle.None
      ]
   ), 
   rows_skip = Table.Skip(get_table, 6), 
   tab_headers = Table.PromoteHeaders(
      rows_skip, 
      [PromoteAllScalars = true]
   ), 
   rows_select_3 = Table.SelectRows(tab_headers, each ([Pos ID] = "")), 
   tab_add_col = Table.AddColumn(
      rows_select_3, 
      "Дата", 
      each Date.From(
         Text.BetweenDelimiters(get_table[Column2]{3}, ": ", " ")
      ), 
      type date
   ), 
   cols_types = Table.TransformColumnTypes(
      tab_add_col, 
      {{"Себестоимость", type number}, {"Остаток на складе", Int64.Type}}
   )
in
   cols_types