Power Query Power Query. Работа с ошибками

Power Query Ошибки №19. Неверная разбивка на столбцы

Файлы к уроку:

Ссылки:

Описание

Вы импортируете данные из TXT/CSV. Все почти получается, но некоторые строки разбиваются на столбцы неверно.

Решение

Сначала нужно отфильтровать строки, которые разбиваются на столбцы неправильно. Это делается временно, чтобы понять как их обработать.

При импорте CSV важно не разбивать данные на столбцы. Все нужно импортировать одним столбцом.

Далее нужно определиться в каком именно месте деление происходит неверно. Для этого нужно отрезать понемногу данные из импортированного столбца с помощью функций Text.AfterDelimiter и Text.BeforeDelimiter.

Когда получится локализовать столбец с ошибками нужно будет удалить из него лишние символы.

Примененные функции

Csv.Document
QuoteStyle.None
Table.AddIndexColumn
Table.SelectRows
Table.RemoveColumns
Table.AddColumn
Text.AfterDelimiter
RelativePosition.FromEnd
Text.BeforeDelimiter
Table.TransformColumns
Text.Remove
Table.CombineColumns
Combiner.CombineTextByDelimiter
Table.SplitColumn
Splitter.SplitTextByDelimiter
QuoteStyle.Csv
Table.PromoteHeaders

Код

let
   source = Csv.Document(
      File.Contents(
         Excel.CurrentWorkbook(){[Name = "path"]}[Content]{0}[Column1] & "\data.txt"
      ), 
      [Encoding = 1251, QuoteStyle = QuoteStyle.None]
   ), 
   tab_index_col = Table.AddIndexColumn(source, "Индекс", 0, 1, Int64.Type), 
   rows_select = Table.SelectRows(
      tab_index_col, 
      each ([Индекс] = 3 or [Индекс] = 17 or [Индекс] = 0)
   ), 
   cols_select = Table.RemoveColumns(rows_select, {"Индекс"}), 
   tab_col_text = Table.AddColumn(
      cols_select, 
      "Текст перед разделителем", 
      each Text.AfterDelimiter([Column1], "#(tab)", {6, RelativePosition.FromEnd}), 
      type text
   ), 
   tab_col_text_2 = Table.AddColumn(
      tab_col_text, 
      "Текст перед разделителем.1", 
      each Text.BeforeDelimiter([Column1], "#(tab)", 1), 
      type text
   ), 
   col_transform_1 = Table.TransformColumns(
      tab_col_text_2, 
      {{"Column1", each Text.AfterDelimiter(_, "#(tab)", 1), type text}}
   ), 
   col_transform_2 = Table.TransformColumns(
      col_transform_1, 
      {
         {
            "Column1", 
            each Text.BeforeDelimiter(_, "#(tab)", {6, RelativePosition.FromEnd}), 
            type text
         }
      }
   ), 
   col_transfrom_3 = Table.TransformColumns(
      col_transform_2, 
      {{"Column1", each Text.Remove(_, {"#(tab)"}), type text}}
   ), 
   tab_combine_cols = Table.CombineColumns(
      col_transfrom_3, 
      {"Текст перед разделителем.1", "Column1", "Текст перед разделителем"}, 
      Combiner.CombineTextByDelimiter("#(tab)", QuoteStyle.None), 
      "Сведено"
   ), 
   col_split = Table.SplitColumn(
      tab_combine_cols, 
      "Сведено", 
      Splitter.SplitTextByDelimiter("#(tab)", QuoteStyle.Csv), 
      {
         "Сведено.1", 
         "Сведено.2", 
         "Сведено.3", 
         "Сведено.4", 
         "Сведено.5", 
         "Сведено.6", 
         "Сведено.7", 
         "Сведено.8"
      }
   ), 
   tab_headers = Table.PromoteHeaders(col_split, [PromoteAllScalars = true])
in
   tab_headers

Курс по ошибкам в Power Query

Номер урока	Урок	Описание
1	Power Query Ошибки №1. Измененный тип, Неверная фильтрация в UI	Почему возникает ошибка Expression.Error Столбец таблицы не найден? Одна из причин — шаг Измененный тип. Почему в вашей итоговой таблицы не все данные, которые должны там оказаться? Вероятно вы совершили ошибку неверной фильтрации в пользовательском интерфейсе.
2	Power Query Ошибки №2. Фиксированная ширина столбца Excel	В этом уроке вы узнаете как отключить автоматическое определение ширины столбцов таблицы Excel при обновлении запроса Power Query.
3	Power Query Ошибки №3. Formula Firewall, запрос ссылается на…	Вы работаете в Power Query, но при попытке обновить все возникает ошибка Formula Firewall, запрос ссылается на… Что делать? Как исправить?
4	Power Query Ошибки №4. Доступ к веб-содержимому	В этом уроке вы узнаете как избавиться от надоедливого окна доступ к веб-содержимому.
5	Power Query Ошибки №5. Количество столбцов CSV	При импорте CSV получается неверное количество столбцов.
6	Power Query Ошибки №6. Не получается изменить тип данных (DataFormat.Error)	При попытке изменить тип данных с текстового на дату возникает ошибка DataFormat.Error.
7	Power Query Ошибки №7. Разные имена листов	В этом уроке мы решим проблему, когда в ваших источниках нужные вам данные находятся всегда на листах с разными именами.
8	Power Query Ошибки №8. Разные имена листов 2	В этом уроке мы другими способами решим проблему, когда в ваших источниках нужные вам данные находятся всегда на листах с разными именами.
9	Power Query Ошибки №9. Разные имена столбцов, Table.TransformColumnNames	В этом уроке мы разберем проблему, когда нам присылают файлы, в которых всегда столбцы названы по-разному.
10	Power Query Ошибки №10. Как развернуть все столбцы	В этой задаче мы научимся разворачивать все столбцы табличного столбца не перечисляя каждый из них хардкодом.
11	Power Query Ошибки №11. Подключиться к последнему файлу	В этом уроке мы научимся подключаться к самому свежему файлу из нужной нам папки с нужным названием.
12	Power Query Ошибки №12. Консолидация и MissingField.Type	Бывает вы ходите выполнить добавление таблиц друг под другом с предварительной обработкой, но получаете ошибку Expression.Error: Столбец таблицы не найден.
13	Power Query Ошибки №13. Удалить пустые столбцы	Как без хардкода автоматически удалить пустые столбцы в Power Query, которые есть в импортируемой таблицы. Разберем 2 способа. Один из них прост до безобразия, а для второго понадобится функция Table.Profile.
14	Power Query Ошибки №14. Удалить лишние пробелы	В этом уроке мы разберем еще 1 способ удалить лишние пробелы в текстовом столбце Power Query. Для этого мы повторим и изучим несколько новых функций. Text.SplitAny List.Select Character.FromNumber Text.Combine
15	Power Query Ошибки №15. Плохо структурированный TXT	Как быть, если текстовый файл разбивается на столбцы неправильно?
16	Power Query Ошибки №16. При округлении не совпадает общая сумма	Разберем ошибку, которая возникает при необходимости разбить число на определенные доли, а результаты округлить до двух знаков после запятой. В такой ситуации может получиться, что сумма слагаемых не будет равняться исходному числу.
17	Power Query Ошибки №17. Удаление дубликатов, Подводные камни Table. Distinct	Что может пойти не так при использовании функции удаления дубликатов.
18	Power Query Ошибки №18. Удаление дубликатов 2, Подводные камни Table. Distinct	Что может пойти не так при использовании функции удаления дубликатов. Другое решение данной проблемы.
19	Power Query Ошибки №19. Неверная разбивка на столбцы	При импорте данных из CSV или TXT разбивка на столбцы происходит неправильно.
20	Power Query Ошибки №20. Пустая таблица при импорте Excel (XLSX, XLS)	Вы пытаетесь подключиться к книге Excel, но импортируется пустая таблица.
21	Power Query Ошибки №21. Подключение к PostgreSQL, Установка драйвера	Вы пытаетесь подключиться к PostgreSQL и получаете ошибку «Перед использование этого соединителя необходимо установить один или несколько дополнительных компонентов»

предыдущая запись

Tableau Базовый №4. Таблицы (Tables)

следующая запись