Power Query. Ошибки. Автоматическое удаление пустых столбцов

---

Описание

Ваша таблица источник имеет множество пустых столбцов. Пустыми всегда оказываются разные столбцы, поэтому у вас появилась необходимость создать универсальное решение, распознающее пустые столбцы и удаляющее их.

Решение

Допустим вы часто получаете данные, в которых часто бывают лишние пустые столбцы. У всех у них всегда разные называния. Хочется их удалять автоматически, чтобы они не мешали.

В этом уроке разберем 2 способа автоматически удалять пустые столбцы в Power Query.

Первый способ — это использование функции Table.Profile, а для решения этой задачи вторым способом нам понадобится только пользовательский интерфейс.

Примененные функции

• Table.Profile
• Table.AddColumn
• Table.SelectRows
• Table.RemoveColumns
• Table.UnpivotOtherColumns
• Table.Pivot
• List.Distinct

Код

Решение с использованием Table.Profile:

let
   source = Excel.CurrentWorkbook(){[Name = "Данные"]}[Content], 
   tab_profile = Table.Profile(source), 
   tab_add_col_1 = Table.AddColumn(
      tab_profile, 
      "Пользовательская", 
      each [Count] = [NullCount]
   ), 
   rows_select = Table.SelectRows(
      tab_add_col_1, 
      each [Пользовательская] = true
   ), 
   cols_select = Table.RemoveColumns(source, rows_select[Column])
in
   cols_select

Решение с использованием только пользовательского интерфейса:

let
   source = Excel.CurrentWorkbook(){[Name = "Данные"]}[Content], 
   tab_unpivot = Table.UnpivotOtherColumns(
      source, 
      {"№"}, 
      "Атрибут", 
      "Значение"
   ), 
   tab_pivot = Table.Pivot(
      tab_unpivot, 
      List.Distinct(tab_unpivot[Атрибут]), 
      "Атрибут", 
      "Значение"
   )
in
   tab_pivot